5 Stikprøveberegning

Proceduren proc power benyttes til at lave styrkeberegninger. Der findes et hav af af muligheder, her beskrives kun hvordan man laver beregningen for et two-sample t-test og et test i en 2x2 tabel. Se SAS’ hjemmeside om proc power for flere muligheder.

5.1 Sammenligning af to gennemsnit

Eksempel: Two-sample t-test (uge 2)

Når man ønsker at sammenligne middelværdien i to grupper ved et t-test skal man have fat i twosamplemeans som første del af en kommandolinie. Desuden skal man specificere at man ønsker at teste differensen mellem de to grupper med test=diff. Herefter specificerer man de værdier man ønsker beregningerne udført for, og man kan fylde flere værdier ind for de forskellige størrelser (derved undgår man at skulle køre proc power for alle mulige kombinationer af værdierne). Den værdi man ønsker SAS skal beregne, skal sættes til missing (.).

Et eksempel hvor vi har SD=20 eller 28, gennemsnitlig forskel på 5, ønsker antal i hver gruppe bestemt for en power på hhv 0.8 og 0.9 er:

proc power;
   twosamplemeans test=diff
   meandiff=5
   stddev=20,28
   npergroup=.
   power=0.8,0.9;
run;

Bemærk at vi altså ikke indlæser et datasæt her, men selv fylder værdierne ind. Flere værdier til en option (her power) adskilles af et komma.

Ønsker man i stedet at bestemme power ud fra en given gruppestørrelse sætter man i stedet power til manglende (.) og angiver npergroup, f.eks.

proc power;
   twosamplemeans test=diff
   meandiff=5
   stddev=20
   npergroup=200
   power=.
run;

Man kan tilmed udføre beregninger med forskellig gruppestørrelse, f.eks. kunne vi ønske at randomisere 3:1 (således at vi har 3/4 i den ene gruppe, 1/4 i den anden). Det gøres ved at specificere groupweights og samtidigt angive, at vi ønsker at bestemme feks ntotal:

proc power;
    twosamplemeans test=diff
  meandiff=5 
  stddev=20 
  power=.8 
  groupweights = 3 | 1 
    ntotal=.;
run;    

Bemærk at gruppevægtene her adskilles af |, man kan dog også skrive groupweights=(3 1);

5.2 Sammenligning af to hyppigheder

Med twosamplefreq angiver vi at vi ønsker at sammenligne andele (frekvenser) for to stikprøver. test kan være enten fisher eller pchi (for hhv Fisher eller chi-i-anden (pchi står formentligt for Pearson CHI-i-anden)). Man kan enten angive andelene i de to grupper (her hhv 0.01 og 0.04):

proc power;
    twosamplefreq test=fisher
    groupproportions = (.01 .04)
    npergroup = .
    power = 0.8,0.9;
run;

eller man kan angive andelen i referencegruppen sammen med f.eks. relativ risiko

proc power;
    twosamplefreq test=fisher
    relativerisk = 4
    refproportion = 0.01
    npergroup = .
    power = 0.8,0.9;
run;

Bemærk at vi altså ikke indlæser et datasæt her, men selv fylder værdierne ind. Flere værdier til en option (her power) adskilles af et komma.

Igen kan vi have forskellig gruppestørrelse, … mange muligheder!