6 Ikke-parametriske tests

6.1 One-sample tests

Eksempel: Slagvolumen målt ved to metoder (parrede målinger, uge 1), analyse af differenserne.

Først defineres differenserne:

data ms;
    set ms; 
    dif=mf-sv;
run;

Både Sign-testet og Wilcoxon signed rank test kan findes vha proc univariate benyttet i sin simplest mulige form:

proc univariate data=ms;
    var dif; 
run;

P-værdien for de to tests aflæses i blok med navn ‘Tests for Location: Mu0=0’ i linjen svarende til ‘Sign’ hhv ‘Signed Rank’

6.2 Wilcoxon two-sample / Kruskal-Wallis fler-sample test

Eksempel: Vitamin D (danske og irske kvinder, uge 1/2)

Wilcoxon (for præcis to grupper) og Kruskal-Wallis (for mindst to grupper) findes ved proc npar1way (Non PARametric 1 WAY). Responsvariablen angives i en var-linje, den forklarende variabel i en class-linje. Har den forklarende variabel to niveauer (som i eksemplet her) får man både Wilcoxon og Kruskal-Wallis, har den flere niveauer får man kun ‘Kruskal-Wallis’.

proc npar1way wilcoxon data=vit;
    where country in (1,4);
    class country;
    var vitd;
run;

Med en ekstra linje exact hl får man beregnet p-værdierne eksakt (god idé for meget små datasæt eller meget skæve fordelinger), hvor hl angiver at man vil have konfidensintervaller for forskel i location (forskel i medianer hvis fordelingen i grupperne er af samme form - ellers er det lidt uklart hvad denne størrelse er). WARNING: Disse beregninger kan være tunge - husk at gemme dit program inden i tilfælde af at dit program går ned … min computer kunne ikke køre nedenstående stump på et par minutter

proc npar1way wilcoxon data=vit;
    where country in (1,4);
    class country;
    exact hl;
    var vitd;
run;

6.2.1 Median test

Median testet kan fås via proc npar1way med ekstra option median i proc-linjen:

proc npar1way wilcoxon data=vit median;
    where country in (1,4);
    class country;
    var vitd;
run;

P-værdien aflæses i blok med titel ‘Median Two-Sample Test’ hhv ‘Median One-Way Analysis’ afhængigt af om class-variablen har to eller flere grupper.