FILENAME goptions URL "http://192.38.117.59/~linearpredictors/datafiles/goptions.sas";
%include goptions;

FILENAME url URL "http://192.38.117.59/~linearpredictors/datafiles/readVitaminD.sas";
%include url;

DATA irishwomen;
	SET vitamind (WHERE = (country=4 and category=2));
RUN;

PROC REG DATA = irishwomen;
    MODEL vitd=bmi / CLB;
    OUTPUT OUT = results p=predicted r=residual cookd=cookd;
RUN;

PROC SORT DATA=RESULTS;
    BY bmi;
RUN;

%begin_multilayout(2,2);

/*
Scatter plot of Residuals against BMI
*/

PROC GPLOT DATA = results GOUT=plots; 
    PLOT residual*bmi /
        HAXIS=AXIS1 VAXIS=AXIS2;
    AXIS1
        MINOR = NONE
        OFFSET = (5 pct)
        LABEL = ('BMI');
    AXIS2
        MINOR = NONE
        LABEL = (A=90 R=0 'Residual');
    SYMBOL1 VALUE = CIRCLE I=sm70 COLOR = black;
RUN;

/*
Scatter plot of Residuals against predicted values of Vitamin D
*/

PROC GPLOT DATA = results GOUT=plots; 
    PLOT residual*predicted /
        VREF=0 LV=33 HAXIS=AXIS1 VAXIS=AXIS2;
    AXIS1
        MINOR = NONE
        OFFSET = (5 pct)
        LABEL = ('Predicted value of BMI');
    AXIS2
        MINOR = NONE
        LABEL = (A=90 R=0 'Residual');
    SYMBOL1 VALUE = CIRCLE I=none COLOR = black;
RUN;

/*
Histogram of residuals, and residual plot
*/
    
PROC UNIVARIATE NORMAL DATA = results GOUT=plots; 
    VAR residual;  
    HISTOGRAM / NORMAL MIDPOINTS=-60 TO 60 BY 10;
    PROBPLOT /  normal(mu=EST sigma=EST l=33);
RUN;

%end_multilayout(2,2);