/* --------------------------------------------------------------- */
/* --------------------------------------------------------------- */

/* Uge 3: Kategoriske data. Tabeller */

/* --------------------------------------------------------------- */
/* --------------------------------------------------------------- */




/* Video 1: Sandsynligheder og binomialfordelingen (slide 1-26) */

* Ingen syntaks;




/* Video 2: Tabeller. Relativ risiko, odds ratio. Case-kontrol 
   studier (slide 27-72) */

* ***;
* *** Slide 34-35 *** *;

data gender;
	input type$ antal;
	datalines;
D 7 
P 1
;
run;

proc freq data=gender;
	tables type / binomial(p=0.5);
	exact binomial;
	weight antal; /* fordi vi ikke skriver alle 8 linier */
run;


* ***;
* *** Slide 39-40 *** *;

data farveblind;
	input gender $ farveblind $ antal;
datalines;
pige nej 119
pige ja 1
dreng nej 144
dreng ja 6
;
run;
proc sort data=farveblind;
	by gender;
run;	
* beregning af CI - bemærk at SAS hakker nedre CI af ved 0 for piger
  og derfor finder nedre CI til 0 og ikke -.008 som angivet i slides.
  Lene har derfor lavet den i hånden som p+/-1.96*sqrt(p*(1-p)/n) med
  p=.0083, n=120 (nedre CI skulle være angivet som  -.0079 og ikke -.0080)
  ;
proc freq data=farveblind;
	tables farveblind / binomial;
	exact binomial;
	weight antal; 
	by gender;
run;


* ***;
* *** Slide 45-56 *** *;
proc freq data=farveblind;
	tables gender*farveblind / nopercent nocol chisq 
							   expected riskdiffc relrisk;
	exact riskdiff;
	weight antal;
run; 


* ***;
* *** Slide 60 *** *;

proc power;
	twosamplefreq test=fisher
	groupproportions = (.01 .04)
	npergroup = .
	power = 0.8,0.9;
run;


* ***;
* *** Slide 61 *** *;

proc power;
	twosamplefreq test=fisher
	oddsratio = 1.5
	refproportion = 0.01
	npergroup = .
	power = 0.8,0.9;
run;


* ***;
* *** Slide 64-65 - tænkt eksempel *** *;
data farveblind2;
	input gender $ farveblind $ antal;
datalines;
pige nej 58
pige ja 21
dreng nej 62
dreng ja 99
;
run;
proc freq data=farveblind2;
	tables farveblind*gender / nopercent relrisk;
	weight antal;
run; 


* ***;
* *** Slide 67 *** *;

proc power;
	twosamplefreq test=fisher
	oddsratio = 1.5
	refproportion = 0.5
	npergroup = .
	power = 0.8,0.9;
run;


* ***;
* *** Slide 69-73 *** *;

data operation;
	input type $ komplikation $ antal;
datalines;
Gynecological ja 5
Gynecological nej 235
Abdominal ja 35
Abdominal nej 210
Orthopedic ja 6
Orthopedic nej 200
;
run;
proc freq data=operation;
	tables type*komplikation /
		nopercent nocol chisq cellchisq expected;
	weight antal;
run;




/* --- Video 3: Confounding, Simpsons paradox. Parrede binære data (slide 73-82) --- */

* ***;
* *** Slide 74-75 *** *;

data nyresten;
	input size $ treat $ succes $ antal;
datalines;
small A nej 6
small A ja 81
small B nej 36
small B ja 234
large A nej 71
large A ja 192
large B nej 25
large B ja 55
;
run;
proc freq data=nyresten;
	tables treat*succes / nopercent nocol relrisk;
	weight antal;
run;
proc sort data=nyresten; 
	by size; 
run;
proc freq data=nyresten;
	tables treat*succes / nopercent nocol relrisk;
	weight antal;
	by size;
run;


* ***;
* *** Slide 80-83 *** *;

data tuberkulose;
	input A $ B $ antal;
datalines;
+ + 20
+ - 12
- + 2
- - 16
;
run;
proc freq data=tuberkulose;
	tables A*B / norow nocol; 
	exact mcnem; 
	weight antal; 
run;